PepLluis : DataGridView's, Visual Studio

Auto Data Entry Form’s

peplluis — Sun, 29 Jan 2012 18:26:00 GMT

Muchos de los lectores de este blog muestran interés por ejemplos entorno a Windows forms y SQL Express, no hay duda y soy consciente de que este articulo no forma parte de esos “avances que están por venir” ni representa a ninguna novedad tecnológica actual; obviamente lejos de herramientas tan actuales como LightSwitch, sin embargo me complace compartirlo con vosotros pues creo que puede ser un buen soporte para ayudar en la comprensión de ciertos usos y técnicas sobre todo para los que empiezan.

Como digo, este es uno de esos artículos intemporales en varios aspectos, pues describe metodologías “retro” utilizando los clásicos SQL y Forms… si embargo no quiero que perdáis de vista que los “usos” y “técnicas” utilizadas pueden traspasar esa barrera atemporal y utilizarse en cualquier escenario actual… incluso en las nuevas aplicaciones “Metro Style” J

Al diseñar algunos ejemplos, disfruto partiendo de una plantilla de “Consola”, pues debido a la naturaleza y el propósito del mismo, esta concesión me permite “Salirme fuera de pistas” de lo que sería una aplicación comercial, pero a su vez me permite disfrutar de la libertad de construir algo desde los cimientos.

Como su nombre indica el objetivo del siguiente laboratorio es interactuar con la conocida base de datos para pruebas “NorthWnd”, utilizaremos la estructura de cualquiera de sus tablas para “Autogenerar” nuestro form de entrada (con todos sus textboxes) que nos permita añadir un nuevo registro a la tabla a través de un “Enlazador”. A modo de flecos para darle un poco mas de interés, he creído divertido incluir una pequeña funcionalidad que nos permita recorrer la tabla buscando todos los registros según la coincidencia del país introducido el textbox de búsqueda (con LINQ), y un par de botones para recorrer el enlazador, avanzando o retrocediendo a partir de la posición actual en el datagridview.

No creo que sea necesario un detalle mas exhaustivo, prefiero pasar al código, aunque antes quedo a vuestra disposición para continuar y desarrollar esta conversación según consideréis de interés.
Que disfrutéis J

PepLluis,

Imports System.Drawing
Imports System.Windows.Forms
 
Imports System.Data
Imports System.Data.SqlClient
 
'
'
' Establecer un punto de entrada. Esto es una aplicacion VB
'
Module MiAplicacion
    Sub Main()
        Dim Ventana As New frmDinamico
        Ventana.Show()
        Application.Run()
    End Sub
End Module
 
 
Public Class frmDinamico
    Inherits Form
    'Punto de Inicializacion de nuestra ventana
 
    'Definicion de Variables de contexto
    Private MiConexion As New SqlConnection(
     "Data Source=.\SQLEXPRESS;" +
     "AttachDbFilename=D:\Bd_App\NORTHWND.MDF;" +
     "Integrated Security=True;Connect Timeout=30;User Instance=True")
 
    ' Adaptador, Enlazador y juego de datos para la tabla clientes
    Private MiAdaptador As New SqlDataAdapter("Select * from Customers", MiConexion)
    Private MiEnlazador As New BindingSource
    Private MiDataSet As New DataSet
 
    ''' <summary>
    ''' Al lanzar la ejecucion de la app
    ''' </summary>
    ''' <remarks></remarks>
    Sub New()
        Try
            Inicializacion()
        Catch fallo As Exception
            Messagebox.Show(fallo.Message, "Error Grave... no puedo continuar")
            End
        End Try
    End Sub
 
    ''' <summary>
    ''' Inicializar/Construir los objetos de la aplicacions
    ''' </summary>
    ''' <remarks></remarks>
    Sub Inicializacion()
        Me.Text = "Auto Entry Data Form"
        ' Crear y Enlazar datos
        Dim MiCommandBuild As New SqlCommandBuilder(MiAdaptador)
        MiConexion.Open()
        MiAdaptador.Fill(MiDataSet)
        MiENlazador.DataSource = MiDataSet.Tables(0)
        Dim MiDataGridView As New DataGridView
        MiDataGridView.DataSource = MiENlazador
        MiDataGridView.Anchor = AnchorStyles.Left Or AnchorStyles.Right Or AnchorStyles.Top
        MiDataGridView.Dock = DockStyle.Top
        '
        ' Añadir los controles al Form
        Me.Controls.Add(MiDataGridView)
        Me.Controls.AddRange({
            New TextBox With {.Name = "Buscar", .Text = "", .Dock = DockStyle.Bottom},
            New Button With {.Name = "Añadir", .Text = .Name, .Dock = DockStyle.Bottom},
            New Button With {.Name = "Avanza", .Text = .Name, .Dock = DockStyle.Bottom},
            New Button With {.Name = "Retrocede", .Text = .Name, .Dock = DockStyle.Bottom}
            })
        ' Apuntar los handlers a sus funciones
        AddHandler Me.Controls("Añadir").Click, AddressOf Nuevo
        AddHandler Me.Controls("Avanza").Click, AddressOf Avanzar
        AddHandler Me.Controls("Retrocede").Click, AddressOf Retroceder
        AddHandler Me.Controls("Buscar").TextChanged, AddressOf Seleccionar
        Me.Controls("Buscar").Focus()
    End Sub
 
    ''' <summary>
    ''' Al final la ejecucion de la app
    ''' </summary>
    ''' <remarks></remarks>
    Sub Fin() Handles Me.FormClosed
        Application.ExitThread()
        End
    End Sub
 
    ''' <summary>
    ''' Query para seleccionar solo los registros coincidentes
    ''' con la cadena de texto introducida en el TextBox 'Buscar'
    ''' </summary>
    ''' <remarks></remarks>
    Sub Seleccionar()
        MiENlazador.DataSource =
                        (
                         From S In MiDataSet.Tables(0)
                          Where S.Item("Country").Contains(Me.Controls("Buscar").Text)
                          Select Nombre = S.Item("CompanyName"),
                                 Ciudad = S.Item("City")
                        ).ToList
    End Sub
 
    ''' <summary>
    ''' Enlazador : MoveNext
    ''' </summary>
    ''' <remarks></remarks>
    Sub Avanzar()
        MiEnlazador.MoveNext()
    End Sub
 
    ''' <summary>
    ''' Enlazador : MovePrevious
    ''' </summary>
    ''' <remarks></remarks>
    Sub Retroceder()
        MiEnlazador.MovePrevious()
    End Sub
 
    ''' <summary>
    ''' Crear un nuevo form conteniendo un TextBox y una etiqueta
    ''' con su descripcion para cada columna de la tabla
    ''' </summary>
    ''' <remarks></remarks>
    Sub Nuevo()
        Dim AutoForm As New Form
        AutoForm.Name = "Nuevo"
        AutoForm.Text = "Data Entry Form"
        Dim Pos_x As Integer = 5
        Dim Pos_y As Integer = 10
        Dim Etiqueta As Label
        Dim Entrada As TextBox
 
        For Each col As DataColumn In MiDataSet.Tables(0).Columns
            Etiqueta = New Label
            Etiqueta.Location = New Point(Pos_x, Pos_Y)
            Etiqueta.Text = Col.ColumnName
            Pos_X += Etiqueta.Width
            Entrada = New TextBox
            Entrada.tag = Etiqueta.Text
            Entrada.Location = New Point(Pos_X, Pos_Y)
            AutoForm.Controls.AddRange(New Control() {Etiqueta, Entrada})
            Pos_x = 5
            Pos_Y += Etiqueta.Height + 5
        Next
        AutoForm.height = Pos_y + 75
        AutoForm.Show()
    End Sub
 
End Class

UPDATE ME DEVUELVE ERROR : CON LA FECHA DEL DGV

peplluis — Wed, 27 Apr 2011 11:11:00 GMT

Desbordamiento de SqlDateTime. Debe estar entre 1/1/1753 12:00:00 AM y 12/31/9999 11:59:59 PM.

En determinados escenarios donde intervienen plataformas en múltiples lenguajes, puede ser necesario implementar unas funciones extras para que la interacción entre formatos se realice correctamente. (sin hablar de las excepciones para tener en cuenta si sumamos el tema de zonas horarias).

Una idea seria realizar la adaptación entre la fecha y hora del objeto (en este caso el DGV) y la asignación de los valores que retornaran, cuando los extremos esperan diferentes formatos.

Puedes capturar el “cellFormating” del DGV y controlar la conversión en el “Parse”.

Aquí tienes un Ejemplo :

http://msdn.microsoft.com/es-es/library/system.windows.forms.datagridview(VS.80).aspx

En otras situaciones donde no disponemos de los “Format” y “Parse” podemos optar por creamos nuestra propia estructura…

' Definicion de la estructura para Fecha/Hora

' segun la definicion del lpSystemTime

Structure FechaYHora

Public Año As UInt16

Public Mes As UInt16

Public DiaDeLaSemana As UInt16

Public Dia As UInt16

Public Hora As UInt16

Public Minutos As UInt16

Public Segundos As UInt16

Public Milis As UInt16

End Structure

'Funciones Fecha/Hora sistema

Declare Function GetSystemTime Lib "Kernel32.dll" (ByRef lpSystemTime As FechaYHora) As UInt32

Declare Function SetSystemTime Lib "Kernel32.dll" (ByRef lpSystemTime As FechaYHora) As UInt32

Private MiFechaYHora = New FechaYHora

Sub DelServidor(ByVal FechaHoraOrigen As DateTime)

MiFechaYHora.Año = Convert.ToUInt16(FechaHoraOrigen.Year)

MiFechaYHora.Mes = Convert.ToUInt16(FechaHoraOrigen.Month)

MiFechaYHora.Dia = Convert.ToUInt16(FechaHoraOrigen.Day)

MiFechaYHora.Hora = Convert.ToUInt16(FechaHoraOrigen.Hour)

MiFechaYHora.Minutos = Convert.ToUInt16(FechaHoraOrigen.Minute)

MiFechaYHora.Segundos = Convert.ToUInt16(FechaHoraOrigen.Second)

' luego debeis asignarlo segun convenga... desde o hacia el control

' o llamando a la funcion de asignar la nueva entrada

SetSystemTime(MiFechaYHora)

End Sub

Espero te ayude,
Pep Lluis,

Actualizar dos tablas vinculadas en una vista Maestro-Detalle

peplluis — Mon, 30 Aug 2010 15:44:00 GMT

Una de las consultas comúnmente solicitadas a través del Blog, tiene que ver con la actualización de datos de dos tablas relacionadas en una BD de SQL, o sea actualizar una vista maestro-detalle vinculadas a sendas tablas.

Aunque por obvio y sencillo, las explicaciones acostumbran a ser de lo más diversas y finalmente te das cuenta que la mayoría de ejemplos se inician con un "desparrame" de jergas incomprensivas para la mayoría. Me decido postearos el ejemplo más básico posible, para que a partir de este punto podáis hacerlo crecer a vuestra necesidad.

Espero que os sea útil y despeje vuestras jaquecas cuando se trata de lidiar con diversas tablas.
PepLluis,

(Para ejecutar el ejemplo, iniciar Visual Studio y crear un nuevo proyecto 'Winform', añadir dos DataGridView y un Button, copiar / pegar codigo y por supuesto F5)

Imports System.Data.SqlClient
 
Public Class Form1
 
    Private Maestro As SqlDataAdapter
    Private Detalle As SqlDataAdapter
    Private ConjuntoDeDatos As DataSet
 
    Private Sub Form1_Load() Handles MyBase.Load
 
        Dim miConexion As New SqlConnection("Data Source=.\SQLExpress;Initial Catalog=MaestroDetalle;Integrated Security=True")
 
        Maestro = New SqlDataAdapter("Select * From Maestro", miConexion)
        Dim MaestroCmdBuilder As New SqlCommandBuilder(Maestro)
 
        Detalle = New SqlDataAdapter("Select * From Detalle", miConexion)
        Dim DetalleCmdBuilder As New SqlCommandBuilder(Detalle)
 
        ConjuntoDeDatos = New DataSet
        Maestro.Fill(ConjuntoDeDatos, "Maestro")
        Me.DataGridView1.DataSource = ConjuntoDeDatos
        Me.DataGridView1.DataMember = "Maestro"
 
        Detalle.Fill(ConjuntoDeDatos, "Detalle")
        Me.DataGridView2.DataSource = ConjuntoDeDatos
 
        ConjuntoDeDatos.Relations.Add("Fk", ConjuntoDeDatos.Tables("Maestro").Columns("IdMaestro"),
                                            ConjuntoDeDatos.Tables("Detalle").Columns("IdDetalle"))
 
        Me.DataGridView2.DataMember = "Maestro.Fk"
    End Sub
 
    Private Sub Actualizar() Handles Button1.Click
        If ConjuntoDeDatos.HasChanges Then
            Maestro.Update(ConjuntoDeDatos, "Maestro")
            Detalle.Update(ConjuntoDeDatos, "Detalle")
        End If
    End Sub
End Class

De un DGV a una MDB

peplluis — Wed, 25 Aug 2010 14:52:00 GMT

Debido a la insistencia de algunos lectores de este blog, me complace retomar un antiguo ejemplo donde rellenamos un DGV con los datos de una hoja XLS y posteriormente creamos una BD con la tabla correspondiente y en formato MDB. Por lo tanto seguro que con las nuevas herramientas podremos realizar tareas similares con mucho menos código, por eso matizo que se trata de un ejemplo reanimado de 2005 al 2010 J

Las versiones tanto de la XLS como la MDB corresponden al 97-2003. Para poder ejecutar este ejemplo necesitas crear un nuevo proyecto 'Winforms' en VB y simplemente copiar y pegar el código en el 'form1'.

Tenéis que tener en cuenta para que funcione necesitas guardar tu hoja en la carpeta del proyecto 'Bin/Debug' (o reléase) según estés compilando y con el nombre 'Libro1.xls'.

No dudéis en contactar conmigo para aclarar cualquier duda, además si necesitas el proyecto el completo estaré encantado de facilitártelo (Lo tengo para Visual Studio 2010).

Espero vuestras valoraciones.
Happy reentrada!
Pep Lluis,

' --------------------------------------------------------------------------------------------
' * AVISO IMPORTANTE * Este programa es propiedad (c)2010 Pep Lluis Bano.
' * AVISO IMPORTANTE * Se autoriza su uso, solo con fines formativos.
' 
' EL USO DE ESTA APLICACION IMPLICA LA ACEPTACION DE LAS CONDICIONES DE USO QUE SE APLICAN
' AL PROGRAMARIO "Open Source", ESTE PROGRAMA SE PROPORCIONA "COMO ESTA", NO OBLIGANDO AL 
' AUTOR A CONTRAER COMPROMISO ALGUNO PARA CON QUIENES LO UTILICEN, ASI COMO DECLINANDO 
' CUALQUIER REPONSABILIDAD DIRECTA O INDIRECTA, CONTRAIDA POR LOS MISMOS EN SU UTILIZACION 
' FUERA DE LOS PROPOSITOS PARA EL QUE FUE ESCRITO Y DISEÑADO.
'
' CUALQUIER MODIFICACIÓN Y DISTRIBUCION DEL MISMO DEBERA CONTENER Y CITAR SU FUENTE Y ORIGEN.
'
' ASI MISMO EL AUTOR AGRADECERA CUALQUIER COMENTARIO o CORRECCION QUE LOS LECTORES CONSIDEREN
' CONTRIBUYENDO ESTOS ULTIMOS A MEJORAR LA APLICACION CON FINES FORMATIVOS.
' CONSIDEREN ENVIAR SUS COMENTARIOS ulizando la opcion [Contact]

' --------------------------------------------------------------------------------------------


Imports ADOX
Imports System.Data.OleDb
Imports System.Text.RegularExpressions
 
Public Class Form1
    'Definir conexion,adaptador y Dataset
    Private MiXlsConexion As OleDbConnection
    Private MiXlsAdaptador As OleDbDataAdapter
    Private MiXlsDataSet As New DataSet()
    Private MiXlsDGV As New DataGridView
 
    Private MiMdbConexion As New OleDbConnection
    Private MiMdbAdaptador As New OleDbDataAdapter
    Private MiMdbDataSet As New DataSet()
 
    Private Mienlazador As New BindingSource
    Private MiMdbDGV As New DataGridView
 
    Private Sub Form1_FormClosing(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosingEventArgs) Handles Me.FormClosing
        MiMdbConexion.Close()
    End Sub
 
    Private Sub Form1_Load() Handles MyBase.Load
        Dim MiXlsEtiqueta As New Label
        MiXlsEtiqueta.Text = "Contenido de la Hoja Excel"
        MiXlsEtiqueta.TextAlign = ContentAlignment.MiddleCenter
        MiXlsEtiqueta.BorderStyle = BorderStyle.Fixed3D
        MiXlsEtiqueta.BackColor = Color.Green
        MiXlsEtiqueta.ForeColor = Color.White
        MiXlsEtiqueta.Dock = DockStyle.Top
 
        Dim MiXlsDGBPanel As New Panel
        MiXlsDGBPanel.AutoSize = True
        MiXlsDGV.Dock = DockStyle.Top
        MiXlsDGBPanel.Controls.AddRange(New Control() {MiXlsDGV, MiXlsEtiqueta})
 
 
        Dim MiMdbEtiqueta As New Label
        MiMdbEtiqueta.Text = "Contenido de la BD resultante"
        MiMdbEtiqueta.TextAlign = ContentAlignment.MiddleCenter
        MiMdbEtiqueta.BorderStyle = BorderStyle.Fixed3D
        MiMdbEtiqueta.BackColor = Color.Maroon
        MiMdbEtiqueta.ForeColor = Color.White
        MiMdbEtiqueta.Dock = DockStyle.Top
 
        Dim MiMdbDGBPanel As New Panel
        MiMdbDGBPanel.AutoSize = True
        MiMdbDGV.Dock = DockStyle.Top
        MiMdbDGBPanel.Controls.AddRange(New Control() {MiMdbDGV, MiMdbEtiqueta})
 
        Dim BotonDeActualizar As New Button
        BotonDeActualizar.Dock = DockStyle.Bottom
        BotonDeActualizar.Text = "Generar Archivo MDB"
 
        Me.AutoSize = True
        Me.Text = "De XLS a MDB"
        MiXlsDGBPanel.Dock = DockStyle.Top
        MiMdbDGBPanel.Dock = DockStyle.Top
        Me.Controls.AddRange(New Control() {MiMdbDGBPanel, MiXlsDGBPanel, BotonDeActualizar})
        AddHandler BotonDeActualizar.Click, AddressOf GenerarMdb
 
        LeerXls()
    End Sub
 
    Private Sub LeerXls()
        'Abrir y llenar el DGV con la hoja de excel
        MiXlsConexion = New OleDbConnection _
        ("Provider=Microsoft.Jet.OLEDB.4.0;" + _
         "Extended Properties = 'Excel 8.0';" + _
         "Data Source=|DataDirectory|\libro1.xls;")
        MiXlsAdaptador = New OleDbDataAdapter("SELECT * FROM [Hoja1$]", MiXlsConexion)
        MiXlsConexion.Open()
        MiXlsAdaptador.Fill(MiXlsDataSet)
        MiXlsDGV.DataSource = MiXlsDataSet.Tables(0)
    End Sub
 
    Private Sub GenerarMdb()
        'Eliminar la BD1 si existe
        If My.Computer.FileSystem.FileExists("Bd1.mdb") Then
            My.Computer.FileSystem.DeleteFile("Bd1.mdb")
        End If
        '
        Dim Nombrede_MiBd = "Bd1.mdb"
        Dim NombreDe_MiTabla = "Detalles"
        ' Para crear una nueva BD de Access, me viene a la
        ' memoria la funcion Catalog del ADOX.DLL
        Dim Catalogo As New ADOX.Catalog()
        Catalogo.Create("Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Nombrede_MiBd)
        '
        ' Una vez creado el nuevo catalogo añadiremos 
        ' la tabla utilizando el suministrador OLEDB
        MiXlsConexion = New OleDb.OleDbConnection("PROVIDER=Microsoft.Jet.OLEDB.4.0;Data Source =" & Nombrede_MiBd)
        '
        ' Obtenendremos el esquema de la nueva BD
        MiXlsConexion.Open()
        Dim MiEsquema As DataTable = MiXlsConexion.GetOleDbSchemaTable(OleDb.OleDbSchemaGuid.Tables, _
                New Object() {Nothing, Nothing, NombreDe_MiTabla, "Detalles"})
        '
        ' El ultimo paso sera crear la estructura en funcion a las columnas de la hoja
        Dim Campos As String = "Create Table [" + NombreDe_MiTabla + "] ("
        For Each col As DataGridViewTextBoxColumn In MiXlsDGV.Columns
            If Campos.EndsWith(")") Or Campos.EndsWith("Key") Then Campos += ", "
            Campos += "[" + Regex.Replace(col.DataPropertyName, " ", "_") + "] Text(50)"
        Next
        Campos += ")"
        Dim MiMandato As New OleDbCommand(Campos, MiXlsConexion)
        MiMandato.ExecuteNonQuery()
        MiXlsConexion.Close()
        '
        ' Añadir todos las filas como registros a la BD
        MiMdbConexion = New OleDb.OleDbConnection("PROVIDER=Microsoft.Jet.OLEDB.4.0;Data Source =" & Nombrede_MiBd)
        MiMdbAdaptador = New OleDbDataAdapter("SELECT * FROM Detalles", MiMdbConexion)
        Dim commandbuilder As New OleDb.OleDbCommandBuilder(Me.MiMdbAdaptador)
        MiMdbConexion.Open()
        MiMdbAdaptador.Fill(MiMdbDataSet)
 
        Dim Registro As DataRow
        For Each row As DataGridViewRow In MiXlsDGV.Rows
            If row.Index < MiXlsDGV.RowCount - 1 Then
                Registro = MiMdbDataSet.Tables(0).NewRow
                For Each col As DataGridViewColumn In MiXlsDGV.Columns
                    'Añadir una entrada por celda
                    Registro(col.Index) = row.Cells(col.Index).Value
                Next
                'Añadir una linea por fila
                MiMdbDataSet.Tables(0).Rows.Add(Registro)
            End If
        Next
        MiMdbAdaptador.Update(MiMdbDataSet)
        MiMdbDGV.DataSource = MiMdbDataSet.Tables(0)
        MiMdbConexion.Close()
    End Sub
End Class

Buscar un texto en una columna y seleccionar los coincidentes en un DGV

peplluis — Fri, 24 Apr 2009 09:13:00 GMT

<Pregunta>
Que tal .. igual no sé si este comentario sea para es hilo, pero tengo un problema .. tengo un datagridview pero quiero agregar un textbox fuera del datagrid, para cuando empiece a escribir vaya buscando en el datagrid y que se vaya seleccionando, sé que para ese procedimiento se juega un poco con el datatable pero aún estoy perdido ... alguién tiene una sugerencia ..

Mil gracias

<Respuesta>
... Se me ocurre algo similar a esto.

Private Articulo As New DataTable("Articulos")

Private MIDGV As New DataGridView

Private MITXT As New TextBox

Private Sub Form1_Load() Handles MyBase.Load

' Simular tabla Articulos

Articulo.Columns.Add("Codigo")

Articulo.Columns.Add("Descripcion")

Articulo.Columns.Add("Precio")

Articulo.Rows.Add("001", "Resistencia 100ohms", "0,15")

Articulo.Rows.Add("002", "Transistor 2n2234", "1,00")

Articulo.Rows.Add("003", "Microprocesador Z80", "5,40")

Articulo.Rows.Add("004", "UART 16C450", "3,45")

Articulo.Rows.Add("005", "Resistencia 200ohms", "0,12")

Articulo.Rows.Add("006", "Transistor 2n2222", "1,22")

' marco

Dim marcoDGV = New FlowLayoutPanel

marcoDGV.BorderStyle = BorderStyle.Fixed3D

marcoDGV.Width = Me.Width

marcoDGV.Height = Me.Height

' Añadir el marco con el DataGridView y textBox

marcoDGV.Controls.AddRange(New Control() {MIDGV, MITXT})

Me.Controls.Add(marcoDGV)

' Seleccionar el textbox

MITXT.Select()

' al cambiar el texto

AddHandler MITXT.TextChanged, AddressOf VerSeleccion

End Sub

' LINQ (Con VB9 'Visual Studio 2008')

' Mostrar la seleccion de los registros

' que contienen la seleccion del texto

' introducido en el textBox

Private Sub VerSeleccion()

MIDGV.DataSource = (From S In Articulo Where S.Item("Descripcion").ToString.Contains(MITXT.Text) _

Select Codigo = S.Item("Codigo"), _

Descripcion = S.Item("Descripcion") _

).ToList

End Sub

Saludos,
Pep Lluis,

Autocompletando columnas en un DataGridView

peplluis — Thu, 16 Apr 2009 08:05:00 GMT

<Pregunta>
Estoy desarrollando una TPV, y he visto muchos ejemplos donde existe un texbox para ingresar el codigo o el producto y despues agregarle al datagrid. Mi pregunta es la siguiente:
Existe la forma de escribir directamente en la grilla y que a medida de ingresar las letras me autocomplete el nombre del producto y luego con enter me trae los otros datos (codigo,precio,etc)?
Saludos

<Respuesta>

Public Class Form1

Private Articulo As New DataTable("Articulos")

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

' Simular tabla Articulos

Articulo.Columns.Add("Codigo")

Articulo.Columns.Add("Descripcion")

Articulo.Columns.Add("Precio")

Articulo.Rows.Add("001", "Resistencia 100oh", "0,15")

Articulo.Rows.Add("002", "Transistor 2n2234", "1,00")

Articulo.Rows.Add("003", "Microprocesador Z80", "5,40")

Articulo.Rows.Add("004", "UART 16C450", "3,45")

Articulo.Rows.Add("001", "Resistencia 200oh", "0,12")

Articulo.Rows.Add("002", "Transistor 2n2222", "1,22")

'Fijar la clave principal para las busquedas

Dim Claves(0) As DataColumn

Claves(0) = Articulo.Columns("Descripcion")

Articulo.PrimaryKey = Claves

'Crear la lista de cadenas para el autocompletado

For Each nombre In Articulo.Rows

CadenasAutocompletado.Add(nombre("Descripcion"))

'Dar formato a la vista de nuestro DGV

Me.DataGridView1.Columns.Add("Codigo", "Codigo")

Me.DataGridView1.Columns.Add("Descripcion", "Descripcion")

Me.DataGridView1.Columns.Add("Precio", "Precio")

End Sub

'Al editar la celda Descripcion

Private CadenasAutocompletado As New AutoCompleteStringCollection

Private Sub ControlEdicion(ByVal sender As Object, ByVal e As DataGridViewEditingControlShowingEventArgs) Handles DataGridView1.EditingControlShowing

If DataGridView1.CurrentCell.ColumnIndex = 1 Then

DirectCast(e.Control, TextBox).AutoCompleteMode = AutoCompleteMode.SuggestAppend

DirectCast(e.Control, TextBox).AutoCompleteSource = AutoCompleteSource.CustomSource

DirectCast(e.Control, TextBox).AutoCompleteCustomSource = CadenasAutocompletado

End If

End Sub

' Completar las columnas de Codigo/Precio al finalizar la edicion

Private Sub FinDeEdicion(ByVal sender As Object, ByVal e As DataGridViewCellEventArgs) Handles DataGridView1.CellEndEdit

'Añadir aqui las validaciones necesarias

Try

Dim _Articulo As DataRow = Articulo.Rows.Find(Me.DataGridView1(e.ColumnIndex, e.RowIndex).Value)

Me.DataGridView1("Codigo", e.RowIndex).Value = _Articulo("Codigo")

Me.DataGridView1("Precio", e.RowIndex).Value = _Articulo("Precio")

Catch ex As Exception

'.... Accion en caso de excepcion

End Try

End Sub

End Class

Establecer una vista Maestro Detalle, entre dos Tablas

peplluis — Tue, 10 Feb 2009 11:10:00 GMT

Más respuestas... a la pregunta:

>> Hola el ejemplo Dos Tablas y sus relaciones en un DataGridView a traves de un 'ComboBoxColumn' estuvo muy bueno pero quería saber cómo hago si solamente quiero mostrar los 2 DataTables tipo maestro detalle en el DataGridView.

' Simular tabla con los Id's Maestros

Dim Maestros As New DataTable("Maestro")

Maestros.Columns.Add("Cliente")

Maestros.Columns.Add("Nombre")

Maestros.Rows.Add("001", "Jose Javier Garcia")

Maestros.Rows.Add("002", "Jhon Smith Carter")

Maestros.Rows.Add("003", "Pierre Bertran Janvier")

Maestros.Rows.Add("004", "Jose Di Souza")

' Simular tabla con los Detalles

Dim Detalles As New DataTable("Detalle")

Detalles.Columns.Add("Cliente")

Detalles.Columns.Add("Pedido")

Detalles.Columns.Add("Fecha")

Detalles.Columns.Add("Importe")

Detalles.Rows.Add("001", "F164533", "22/01/2006", "1,111.11")

Detalles.Rows.Add("001", "A163453", "22/02/2007", "2,123.23")

Detalles.Rows.Add("003", "ZP12343", "22/03/2008", "3,456.34")

Detalles.Rows.Add("004", "PDF2333", "22/05/2009", "4,452.22")

Detalles.Rows.Add("001", "CRF5453", "22/06/2009", "1,223.33")

Detalles.Rows.Add("002", "MFF6763", "22/07/2009", "1,234.32")

Detalles.Rows.Add("002", "VRF4683", "22/08/2009", "2,123.54")

Detalles.Rows.Add("004", "ZRF7933", "22/09/2009", "1,203.00")

' Construir el DS y establecer relaciones

Dim MiDataSet As New DataSet

MiDataSet.Tables.Add(Detalles)

MiDataSet.Tables.Add(Maestros)

MiDataSet.Relations.Add("Fk", _

MiDataSet.Tables("Maestro").Columns("Cliente"), _

MiDataSet.Tables("Detalle").Columns("Cliente"))

' Contructores para los Bingdings

Dim MaestroBindingSource As New BindingSource

Dim DetalleBindingSource As New BindingSource

' Binding del "Maestro"

MaestroBindingSource.DataMember = "Maestro"

MaestroBindingSource.DataSource = MiDataSet

' Enlace del detalle entre la relacion "Fk" y el Maestro

DetalleBindingSource.DataMember = "Fk"

DetalleBindingSource.DataSource = MaestroBindingSource

'Asignar los binding source Maestro y Detalle a su DGV

Me.DataGridView1.DataSource = MaestroBindingSource

Me.DataGridView2.DataSource = DetalleBindingSource

Para probar este ejemplo solo es necesario crear una nueva solución “Windows Forms”, añadir dos DataGridView al Form1 y en el evento “Form Load” añadir el código adjunto. Puedes hacer lo mismo utilizando un 'combo' aunque he preferido dos DataGridView por simplicidad.

Espero os sea útil,
Pep Lluis,

De Excel a Texto pasando por un DataGridView

peplluis — Mon, 09 Jun 2008 22:14:00 GMT

''
'' Crear un archivo de texto con el contenido
'' de las celdas de un DataGridView de los
'' datos cargados de una hoja de excel.
''

Imports System.Data.OleDb

Public Class Form1
    'Definir conexion,adaptador y Dataset
    Private MiConexion As New OleDbConnection _
    ("Provider=Microsoft.Jet.OLEDB.4.0;" + _
     "Extended Properties = 'Excel 8.0';" + _
     "Data Source=|DataDirectory|\libro1.xls;")
    Private MiAdaptador As New OleDbDataAdapter("SELECT * FROM [Hoja1$]", MiConexion)
    Private MiDataSet As New DataSet()

    Private Sub Form1_Load() Handles MyBase.Load
        'Abrir y llenar el DGV con la hoja de excel
        MiConexion.Open()
        MiAdaptador.Fill(MiDataSet)
        Me.DataGridView1.DataSource = MiDataSet.Tables(0)
        'Crear un documento de texto
        Dim ATexto = IO.File.CreateText("MiExport.txt")
        For Each row As DataGridViewRow In Me.DataGridView1.Rows
            For Each col As DataGridViewColumn In Me.DataGridView1.Columns
                'Añadir una entrada por celda
                ATexto.Write(row.Cells(col.Index).Value)
                'separar con un tabulador
                ATexto.Write(Chr(Keys.Tab))
            Next
            'Añadir una linea por fila
            ATexto.WriteLine()
        Next
        ATexto.Close()
    End Sub

End Class

:-)

Totalizar una Columna en un DataGridView

peplluis — Thu, 05 Jun 2008 11:52:00 GMT

Siguiendo la consulta de Jesús Pérez, preguntando como totalizar la suma de una columna de un DataGridView, poniendo como ejemplo recorrer las filas de una columna y efectuar las operaciones que consideremos oportunas. Tambien como entrada del post os dejo un aporte gracias a Enrique Martinez, que introduce la funcion explicita y correcta para efectuar sumas en encolumnados de DataGridView's...

Saludos,
Pep Lluis,

Aqui teneis el enlace : http://msdn.microsoft.com/es-es/library/system.data.datatable.compute.aspx

        ' Computar la suma de la columna 'Capital'
        Dim total As Object = dt.Compute("SUM(Capital)", Nothing)
        ' visualizar el resultado en la barra
        Me.Text = total.ToString

A continuacion... recorriendo las filas de la Columna...

.. Handles Me.Load
'Disparar el calculo cada vez que editamos
AddHandler Me.dataGridView1.CellEndEdit, AddressOf Sumar
'Calcular el contenido inicial de la columna
Me.dataGridView1.Columns(3).HeaderText = "Salario"
Me.dataGridView1.AllowUserToAddRows = False
Me.dataGridView1.CurrentCell = dataGridView1.Rows(0).Cells(3)
Sumar()
..
End Sub
'
' Sumar las cantidades de una columna
'
Private Columna As Integer = 3

Sub Sumar()
Dim Total As Integer = 0      'Acumular el total
Dim UltimaFila As Integer = Me.dataGridView1.Rows.Count
'Solo calculamos si modificamos la columna definida
If Me.dataGridView1.CurrentCell.ColumnIndex = Columna Then
   For Each row As DataGridViewRow In Me.dataGridView1.Rows
   If row.Index < UltimaFila - 1 Then Total += row.Cells(Columna).Value
   Next
   Me.dataGridView1.Rows(UltimaFila - 1).Cells(3).Value = Total.ToString
  End If
End Sub

Pd. No dudeis en pedirme el proyecto completo si estais interesados, o si quereis comentar alguna parte del codigo.

Dos Tablas y sus relaciones en un DataGridView a traves de un 'ComboBoxColumn'

peplluis — Wed, 04 Jun 2008 07:41:00 GMT

Ejemplo de cómo añadir una columna de selección unida a una tabla de ‘maestros’ y relacionada con su identificador en la tabla ‘detalles’, en casos reales solo teneis que substituir las tablas por los ‘sources’ de las tablas en vuestra BD.
Me gustara recibir vuestros comentarios... ;-)

Imports System
Imports System.Data

Public Class Form1
    Private dataGridView1 As New DataGridView()

    Private Sub Form1_Load() Handles Me.Load
        '
        ' Simular tabla con los Detalles
        '
        Dim Detalles As New DataTable("Detalle")
        Detalles.Columns.Add("Actividad")
        Detalles.Columns.Add("Nombre")
        Detalles.Columns.Add("Telefono")
        Detalles.Rows.Add("001", "Pep Lluis", "231.321.321")
        Detalles.Rows.Add("002", "Luis Franco", "Internacional")
        Detalles.Rows.Add("003", "Marc Rubiño", "111.222.333")
        Detalles.Rows.Add("004", "Javier Conesa", "91.244.32.32")
        '
        ' Simular tabla con los Id's Maestros
        '
        Dim Maestros As New DataTable("Maestro")
        Maestros.Columns.Add("Actividad")
        Maestros.Columns.Add("Descripcion")
        Maestros.Rows.Add("001", "POgramaor")
        Maestros.Rows.Add("002", "Torero")
        Maestros.Rows.Add("003", "Banderillero")
        Maestros.Rows.Add("004", "ANALista")

        '
        ' Construir el DS y establecer relaciones
        '
        Dim MiDataSet As New DataSet
        MiDataSet.Tables.Add(Detalles)
        MiDataSet.Tables.Add(Maestros)
        MiDataSet.Relations.Add("Actividad", _
              MiDataSet.Tables("Maestro").Columns("Actividad"),_
              MiDataSet.Tables("Detalle").Columns("Actividad"))
       '
        ' Añadir una columna 'ComboBox'
        ' Conteniendo la tabla 'Maestro'
        '
        Dim MiBoxColumn As New DataGridViewComboBoxColumn
        MiBoxColumn.DisplayMember = "Descripcion"
        MiBoxColumn.ValueMember = "Actividad"
        MiBoxColumn.DataPropertyName = "Actividad"
        MiBoxColumn.DataSource = MiDataSet.Tables("Maestro")
        Me.dataGridView1.Columns.Add(MiBoxColumn)
        '
        ' Visualizar el DGV con la columna combo 'Maestro'
        ' y las columnas y tablas de 'Detalle'
        '
        Me.dataGridView1.Dock = DockStyle.Fill
        Me.Controls.Add(dataGridView1)
        Me.dataGridView1.DataSource = MiDataSet.Tables("Detalle")

   End Sub
End Class

Si os interesa en determinadas situaciones podeis "camuflar" el combo para que tenga un aspecto como este :

De esta forma no podran modificar ni desplegar las opciones y su aspecto sera como el de cualquier otra columna.
Ajustando las propiedades :

MiBoxColumn.DisplayStyle = DataGridViewComboBoxDisplayStyle.Nothing
MiBoxColumn.ReadOnly = True

Saludos,
Pep Lluis,

PD. Agradecemos la participacion de los actores secundarios (Javier, Luis i Marc), aunque tengo mis dudas sobre si son personajes reales o ficticios ;-)

DataGridView... Quiero saltar de de Columna!!! no de fila

peplluis — Mon, 30 Oct 2006 08:12:00 GMT

Muchos de nosotros aprovechamos el control DataGridView como visualizador, sin embargo además puede ser una excelente ayuda para añadir nuevas filas a nuestras estructuras de datos.

En un proceso donde la información se estructura mediante columnas y líneas, el objetivo es introducir nuevas filas con la mayor facilidad posible, es entonces cuando nos percatamos de que por defecto el DataGridView actúa de una forma un tanto inconveniente para nuestro cometido. Cada vez que pulsamos ‘enter’ ya sea en modo ‘edición’ el efecto es que nos crea una nueva fila desplazándose acto seguido a la primera celda de la misma (como en Excel), entonces nos obliga a utilizar los cursores para reubicar el ‘foco’ a la celda donde va a continuar nuestra próxima entrada. Realmente es un inconveniente, pues nos hace perder muchísimo tiempo empleándolo en pulsaciones simplemente inútiles.

Dicho esto, para poder introducir datos de izquierda a derecha tal y como estamos acostumbrados en la mayoría de situaciones en la que manejamos información, podemos recurrir a varios recursos, os proponemos ver como anulando las funciones ‘ProcessDialogKey’ ‘OnKeyDown’ y rescribiendo el código para que la pulsación de una tecla ‘enter’ sea substituida por un ‘tab’ utilizando un ‘sendkeys’, pudiendo conseguir una mejora increíble en la funcionalidad. También en una segunda propuesta os introducimos a como manejar el direccionamiento de selección de las ‘celdas’ de un DataGridView capturando las pulsaciones en el ‘PreProcessMessage’, ambas heredando la funcionalidad DataGridView y añadiendo a esta personalidad propia.

Esperamos que os sea de utilidad… solo tenéis que ¡cortar y pegar!

Pep Lluis y Rafael.

'' (c) Pep Lluis & Rafa Vargas

'' Ambos ejemplos vienen derivados de una inquietud compartida en

'' el ultimo Code Camp del Escorial en el 2006 entre Rafa Vargas y

'' Pep Lluis... no cabe duda del lema 'Comparte y Aprenderas'.

Public Class form1

Private WithEvents _MiDGView1 As New DgvPlus 'Mi DGV, que traduce el 'Enter' en 'Tab'

Private WithEvents _MiDGView2 As New MiDGView 'Mi DGV, que controla la posicion de la celda actual

' al lanzar nuestro form (en el momento de carga)

Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load

'Construir el primer DGV

_MiDGView1.Dock = DockStyle.Left 'Acoplarlo a la izquierda

_MiDGView1.ColumnCount = 4 'con cuatro columnas

_MiDGView1.AutoSizeColumnsMode = DataGridViewAutoSizeColumnsMode.Fill 'Ajustarlo al tamaño

_MiDGView1.Columns(0).HeaderText = "Caso A" 'Etiquetar columna

Me.Controls.Add(_MiDGView1) 'Añadirlo al form

'Construir el segundo DGV

_MiDGView2.Dock = DockStyle.Right

_MiDGView2.ColumnCount = 4

_MiDGView2.AutoSizeColumnsMode = DataGridViewAutoSizeColumnsMode.Fill

_MiDGView2.Columns(0).HeaderText = "Caso B"

Me.Controls.Add(_MiDGView2)

'La ventana (aspecto)

Me.Width = Me._MiDGView1.Width + Me._MiDGView2.Width + 25 'Ajustar el ancho del form

Me.Text = "Pep/Rafa DataGridView" 'Ponerle titulo

End Sub

End Class

' Nuestra personalizacion para MiDGView ---------------------------------------------------------------

Public Class MiDGView

Inherits DataGridView 'Heredar del DataGridView

'Prepocesar mensajes

Public Overrides Function PreProcessMessage(ByRef msg As System.Windows.Forms.Message) As Boolean

If msg.Msg = 257 And msg.WParam.ToInt32 = 13 Then 'Si es 'KeyDown' y 'Enter'

Dim MiCol As Integer = 0

Dim MiFil As Integer = Me.CurrentCell.RowIndex - 1

If Me.CurrentCell.ColumnIndex < Me.ColumnCount - 1 Then 'Si noSalimos del limite

MiCol = Me.CurrentCell.ColumnIndex + 1 'Siguiente columna

End If

If MiFil > -1 Then Me.CurrentCell = Me(MiCol, MiFil) 'Posicionar columna

End If

Return MyBase.PreProcessMessage(msg)

End Function

End Class

' Nuestra personalizacion para DGVPlus ---------------------------------------------------------------

Public Class DgvPlus

Inherits DataGridView 'Heredar del DataGridView

'en el 'processDialogKey'... cuando estamos en edicion

Protected Overrides Function ProcessDialogKey(ByVal keyData As System.Windows.Forms.Keys) As Boolean

If keyData = Keys.Enter Then 'Si es 'enter'

SendKeys.Send(Chr(Keys.Tab)) 'Enviar un 'Tab'

Return True 'Marcar como procesado

Else 'en caso contrario

Return MyBase.ProcessDialogKey(keyData) 'devolver KeyData

End If

End Function

' en 'OnKeyDown'... cuando no estamos en edicion

Protected Overrides Sub OnKeyDown(ByVal e As System.Windows.Forms.KeyEventArgs)

If e.KeyData = Keys.Enter Then 'Si es 'enter'

SendKeys.Send(Chr(Keys.Tab)) 'Enviar un 'Tab'

Else

MyBase.OnKeyDown(e) 'Devolver el KeyEventArgs

End If

End Sub

End Class