Como cambiar de usuario y acceder a otros recursos en una página WEB.
Muchas veces necesitamos acceder a recursos que lamentablemente nuestro usuario o el usuario que estamos corriendo la aplicación no tiene permisos o privilegios como para llegar a él.
Para las aplicaciones web, la mayoría de las veces los usuarios ASPNET, IUSR_nombreservidor e IWAM_nombreservidor son los que el IIS utiliza (o nosotros mismos configuramos) para correr la aplicación.
A continuación detallo una solución que una vez me entregó Leonardo Garcés cuando necesitaba acceder a un servidor de imágenes en donde no tenía como llegar a dichos archivos.
Clase Recurso:
Imports System.Security.Principal
Public Class Recurso
Dim LOGON32_LOGON_INTERACTIVE As Integer = 2
Dim LOGON32_PROVIDER_DEFAULT As Integer = 0
Dim impersonationContext As WindowsImpersonationContext
Declare Function LogonUserA Lib "advapi32.dll" (ByVal lpszUsername As String, _
ByVal lpszDomain As String, _
ByVal lpszPassword As String, _
ByVal dwLogonType As Integer, _
ByVal dwLogonProvider As Integer, _
ByRef phToken As IntPtr) As Integer
Declare Auto Function DuplicateToken Lib "advapi32.dll" ( _
ByVal ExistingTokenHandle As IntPtr, _
ByVal ImpersonationLevel As Integer, _
ByRef DuplicateTokenHandle As IntPtr) As Integer
Declare Auto Function RevertToSelf Lib "advapi32.dll" () As Long
Declare Auto Function CloseHandle Lib "kernel32.dll" (ByVal handle As IntPtr) As Long
Public Function impersonateValidUser(ByVal Usuario As String, _
ByVal Dominio As String, _
ByVal Clave As String) As Boolean
Dim tempWindowsIdentity As WindowsIdentity
Dim token As IntPtr = IntPtr.Zero
Dim tokenDuplicate As IntPtr = IntPtr.Zero
impersonateValidUser = False
If RevertToSelf() Then
If LogonUserA(Usuario, Dominio, Clave, LOGON32_LOGON_INTERACTIVE, LOGON32_PROVIDER_DEFAULT, token) <> 0 Then
If DuplicateToken(token, 2, tokenDuplicate) <> 0 Then
tempWindowsIdentity = New WindowsIdentity(tokenDuplicate)
impersonationContext = tempWindowsIdentity.Impersonate()
If Not impersonationContext Is Nothing Then
impersonateValidUser = True
End If
End If
End If
End If
If Not tokenDuplicate.Equals(IntPtr.Zero) Then
CloseHandle(tokenDuplicate)
End If
If Not token.Equals(IntPtr.Zero) Then
CloseHandle(token)
End If
End Function
Public Sub undoImpersonation()
impersonationContext.Undo()
End Sub
End Class
Ahora adjunto un ejemplo de como utilizarla, Se rescata el Usuario, el Dominio y la Clave de un archivo de configuración.
Dim objRecurso As New Recurso, _
Usuario As String = System.Configuration.ConfigurationSettings.AppSettings.Get("Usuario"), _
Dominio As String = System.Configuration.ConfigurationSettings.AppSettings.Get("Dominio"), _
Clave As String = System.Configuration.ConfigurationSettings.AppSettings.Get("Clave")
If objRecurso.impersonateValidUser(Usuario, Dominio, Clave) Then
MyFileStream = New FileStream("\\Servidor\Carpeta\Imagen.tif", FileMode.Open, FileAccess.Read)
FileSize = MyFileStream.Length
Dim Buffer(CInt(FileSize)) As Byte
MyFileStream.Read(Buffer, 0, CInt(FileSize))
MyFileStream.Close()
objRecurso.undoImpersonation()
'Más código...
Else
'No se pudo cambiar de Usuario
End If
objRecurso = Nothing
Fin ;)