Fetching the reference description
I've always been irritated at how you can't get at the user friendly reference description as displayed in the Access VBA References screen.
When you look at the properties of the reference object you can't see the user friendly name you see on the above screen.
Sub DebugPrintReferences()
Dim ref As Reference
For Each ref In Access.References
Debug.Print ref.Name & " " & _
IIf(ref.IsBroken, "Broken", "") & _
ref.Major & "." & ref.Minor & " " & _
ref.FullPath
Next ref
End Sub
The above code will only show you:
VBA 4.0 C:\Program Files\Common Files\Microsoft Shared\VBA\VBA6\VBE6.DLL
Access 9.0 C:\Program Files\Microsoft Office 2003\OFFICE11\msacc.olb
DAO 5.0 C:\Program Files\Common Files\Microsoft Shared\DAO\dao360.dll
stdole 2.0 C:\WINDOWS\system32\stdole2.tlb
Not very user friendly when you're trying to post to a newsgroup telling someone what needs to be removed or added.
However fellow Access MVP Thomas Möller suggested adding a reference to Microsoft Visual Basic for Applications Extensibility 5.3 and the following code. (Slightly modified)
Sub DebugPrintReferencesIDE()
' For the refIDE to work a reference must be set to Microsoft Visual Basic for
' Applications Extensibility 5.3
Dim refIDE As VBIDE.Reference
For Each refIDE In Access.Application.VBE.ActiveVBProject.References
Debug.Print refIDE.Description & " " & _
IIf(refIDE.IsBroken, "Broken", "") & vbCrLf & _
" " & refIDE.Name & " " & refIDE.Major & "." & refIDE.Minor & " " & refIDE.FullPath
Next refIDE
End Sub
which gives you the following:
Visual Basic For Applications
VBA 4.0 C:\Program Files\Common Files\Microsoft Shared\VBA\VBA6\VBE6.DLL
Microsoft Access 11.0 Object Library
Access 9.0 C:\Program Files\Microsoft Office 2003\OFFICE11\msacc.olb
Microsoft DAO 3.6 Object Library
DAO 5.0 C:\Program Files\Common Files\Microsoft Shared\DAO\dao360.dll
OLE Automation
stdole 2.0 C:\WINDOWS\system32\stdole2.tlb
Microsoft Visual Basic for Applications Extensibility 5.3
VBIDE 5.3 C:\Program Files\Common Files\Microsoft Shared\VBA\VBA6\VBE6EXT.OLB